Problemas de examen de opcin mltiple

Captulo 9: Ciclos de potencia de vapor y combinados

Cengel/Boles-Termodinmica: un enfoque de ingeniera, 4a edicin
(Los valores numricos de las soluciones se pueden obtener si se copian las soluciones EES que se dan,
se pegan en una pantalla EES en blanco, y se oprime el comando Solve. Problemas parecidos, y sus
soluciones, se pueden obtener con facilidad si se modifican los valores numricos.)

Cap. 9-1 Salida de trabajo de un ciclo de Carnot con vapor

Considere un ciclo de Carnot de flujo estable, con agua como fluido de trabajo, que se ejecuta bajo el domo
de saturacin entre los lmites de presin de 10MPa y 50 kPa. El agua cambia de lquido saturado a vapor
saturado durante el proceso de adicin de calor. La salida de trabajo neto para este ciclo es de
(a) 973 kJ/kg (b) 907 kJ/kg (c) 518 kJ/kg (d) 799 kJ/kg (e) 1072 kJ/kg

Respuesta: (c) 518 kJ/kg.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

P1=10000 "kPa"
P2=50 "kPa"

h_fg=ENTHALPY(Steam_NBS,x=1,P=P1)-ENTHALPY(Steam_NBS,x=0,P=P1)
T1=TEMPERATURE(Steam_NBS,x=0,P=P1)+273
T2=TEMPERATURE(Steam_NBS,x=0,P=P2)+273

q_in=h_fg
Eta_Carnot=1-T2/T1
w_net=Eta_Carnot*q_in

Algunas soluciones errneas con equivocaciones frecuentes:

W1_work = Eta1*q_in; Eta1=T2/T1 "Al tomar la eficiencia de Carnot como T2/T1"
W2_work = Eta2*q_in; Eta2=1-(T2-273)/(T1-273) "Al usar C en lugar de K"
W3_work = Eta_Carnot*ENTHALPY(Steam_NBS,x=1,P=P1) "Al usar h_g en vez de h_fg"
W4_work = Eta_Carnot*q2; q2=ENTHALPY(Steam_NBS,x=1,P=P2)-
ENTHALPY(Steam_NBS,x=0,P=P2) "Al usar h_fg a P2"

Cap. 9-2 Eficiencia del ciclo Rankine con vapor

Un ciclo Rankine ideal simple opera entre los lmites de presin de 20 kPa y 3 MPa, con una temperatura de
entrada de 500C. Si se ignora el trabajo de la bomba la eficiencia del ciclo es de

(a) 26% (b) 33% (c) 57% (d) 67% (e) 74%

Respuesta: (b) 33%.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

P1=20 "kPa"
P2=3000 "kPa"
P3=P2
P4=P1

T3=500 "C"
s4=s3

h1=ENTHALPY(Steam_NBS,x=0,P=P1)
v1=VOLUME(Steam_NBS,x=0,P=P1)
w_pump=v1*(P2-P1) "kJ/kg"
h2=h1+w_pump

h3=ENTHALPY(Steam_NBS,T=T3,P=P3)
s3=ENTROPY(Steam_NBS,T=T3,P=P3)
h4=ENTHALPY(Steam_NBS,s=s4,P=P4)

q_in=h3-h2
q_out=h4-h1
Eta_th=1-q_out/q_in

Algunas soluciones errneas con equivocaciones frecuentes:

W1_Eff = q_out/q_in "Al usar la relacin equivocada"
W2_Eff = 1-(h44-h1)/(h3-h2); h44 = ENTHALPY(Steam_NBS,x=1,P=P4) "Usando h_g para h4"
W3_Eff = 1-(T1+273)/(T3+273); T1=TEMPERATURE(Steam_NBS,x=0,P=P1) "Al usar la eficiencia de
Carnot"
W4_Eff = (h3-h4)/q_in "Al ignorar el trabajo de la bomba"

Cap. 9-3 Contenido de humedad a la salida de una turbina

Un ciclo Rankine ideal simple opera entre los lmites de presin de 10 kPa y 4 MPa con una temperatura de
ingreso a la turbina de 500C. La fraccin de masa de vapor que se condensa a la salida de la turbina es
(a) 0% (b) 8% (c) 14% (d) 92% (e) 86%

Respuesta: (c) 14%.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

P1=10 "kPa"
P2=4000 "kPa"
P3=P2
P4=P1

T3=500 "C"
s4=s3

h3=ENTHALPY(Steam_NBS,T=T3,P=P3)
s3=ENTROPY(Steam_NBS,T=T3,P=P3)
h4=ENTHALPY(Steam_NBS,s=s4,P=P4)
x4=QUALITY(Steam_NBS,s=s4,P=P4)
moisture=1-x4

Algunas soluciones errneas con equivocaciones frecuentes:

W1_moisture = x4 "Al tomar la calidad como humedad"
W2_moisture = 0 "Al uuponer un vapor supercalentado"

Cap. 9-4 Salida de potencia de un ciclo Rankine

Una planta de potencia de vapor opera en el ciclo Rankine ideal simple entre los lmites de presin de 10
kPa y 10 MPa, con una temperatura de entrada a la turbina de 500C. La tasa de transferencia de calor en
la caldera es de 800 kJ/s. Si se ignora el trabajo de bombeo la potencia de salida de esta planta es de
(a) 199 kW (b) 1285 kW (c) 470 kW (d) 323 kW (e) 800 kW

Respuesta: (d) 323 kW.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

P1=10 "kPa"
P2=10000 "kPa"
P3=P2
P4=P1

T3=500 "C"
s4=s3

Q_rate=800 "kJ/s"
m=Q_rate/q_in

h1=ENTHALPY(Steam_NBS,x=0,P=P1)
h2=h1 "se ignora el trabajo de bombeo"
"v1=VOLUME(Steam_NBS,x=0,P=P1)
w_pump=v1*(P2-P1)
h2=h1+w_pump"

h3=ENTHALPY(Steam_NBS,T=T3,P=P3)
s3=ENTROPY(Steam_NBS,T=T3,P=P3)
h4=ENTHALPY(Steam_NBS,s=s4,P=P4)

q_in=h3-h2
W_turb=m*(h3-h4)

Algunas soluciones errneas con equivocaciones frecuentes:

W1_power = Q_rate "Al suponer que todo el calor se convierte en potencia"
W2_power = h3-h4 "Al no usar la tasa de flujo msico"
W3_power = Q_rate*Carnot; Carnot = 1-(T1+273)/(T3+273);
T1=TEMPERATURE(Steam_NBS,x=0,P=P1) "Al usar la eficiencia de Carnot"
W4_power = m*(h3-h44); h44 = ENTHALPY(Steam_NBS,x=1,P=P4) "Al tomar h4=h_g"

Cap. 9-5 Intercambiador de Calor de una planta de gas-vapor

Considere una planta de potencia combinada de gas-vapor. El agua se calienta para el ciclo de vapor en un
intercambiador de calor bien aislado por medio de los gases de escape que ingresan a 800 K a una tasa de
110 kg/s y salen a 380 K. El agua entra al intercambiador de calor a 200C y 8 MPa. Si los gases de escape
se tratan como aire con calores especficos constantes a temperatura ambiente, el flujo msico del agua a
travs del intercambiador de calor se vuelve

(a) 22 kg/s (b) 74 kg/s (c) 28 kg/s (d) 16 kg/s (e) 110 kg/s

Respuesta: (a) 22 kg/s.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

m_gas=110 "kg/s"
Cp=1.005 "kJ/kg.K"
T3=800 "K"
T4=380 "K"
Q_gas=m_gas*Cp*(T3-T4)

P1=8000 "kPa"
T1=200 "C"

P2=8000 "kPa"
T2=350 "C"

h1=ENTHALPY(Steam_NBS,T=T1,P=P1)
h2=ENTHALPY(Steam_NBS,T=T2,P=P2)
Q_steam=m_steam*(h2-h1)

Q_gas=Q_steam
Algunas soluciones errneas con equivocaciones frecuentes:
m_gas*Cp*(T3 -T4)=W1_msteam*4.18*(T2-T1) "Al suponer que no hay evaporacin de agua lquida"
m_gas*Cv*(T3 -T4)=W2_msteam*(h2-h1); Cv=0.718 "Al usar Cv para el aire en vez de Cp"
W3_msteam = m_gas "Al tomar como iguales las tasas de flujo msico de dos fluidos"
m_gas*Cp*(T3 -T4)=W4_msteam*(h2-h11); h11=ENTHALPY(Steam_NBS,x=0,P=P1) "Al tomar
h1=hf@P1"

Cap. 9-6 Eficiencia del ciclo Rankine

Un ciclo Rankine ideal sobrecalentado opera entre los lmites de presin de 20 kPa y 10 MPa, y el
sobrecalentamiento ocurre a 3 MPa. La temperatura del valor en las entradas de ambas turbinas es 500C,
y la entalpa del vapor es 3027 kJ/kg a la salida de la turbina de mayor presin, y 2385 kJ/kg a la salida de
la de menor presin. Si se ignora el trabajo de bombeo la eficiciencia del ciclo es del

(a) 26% (b) 32% (c) 57% (d) 40% (e) 60%

Respuesta: (d) 40%.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

P1=20 "kPa"
P2=10000 "kPa"
P3=P2
P4=3000 "kPa"
P5=P4
P6=P1

T3=500 "C"
T5=500 "C"
s4=s3
s6=s5

h1=ENTHALPY(Steam_NBS,x=0,P=P1)
h2=h1

h44=3104 "kJ/kg para verificar los datos que se dieron"

h66=2385 "kJ/kg para verificar los datos que se dieron"

h3=ENTHALPY(Steam_NBS,T=T3,P=P3)
s3=ENTROPY(Steam_NBS,T=T3,P=P3)
h4=ENTHALPY(Steam_NBS,s=s4,P=P4)

h5=ENTHALPY(Steam_NBS,T=T5,P=P5)
s5=ENTROPY(Steam_NBS,T=T5,P=P5)
h6=ENTHALPY(Steam_NBS,s=s6,P=P6)
q_in=(h3-h2)+(h5-h4)
q_out=h6-h1
Eta_th=1-q_out/q_in

Algunas soluciones errneas con equivocaciones frecuentes:

W1_Eff = q_out/q_in "Al usar la relacin equivocada"
W2_Eff = 1-q_out/(h3-h2) "Al ignorar la entrada de calor durante el sobrecalentamiento"
W3_Eff = 1-(T1+273)/(T3+273); T1=TEMPERATURE(Steam_NBS,x=0,P=P1) "Al usar la eficiencia de
Carnot"
W4_Eff = 1-q_out/(h5-h2) "Al usar la relacin equivocada para q_in"
Cap. 9-7 Extraccin de vapor de un alimentador de agua caliente (FWH)
Se calentar un alimentador de agua presurizado en una planta de potencia de vapor en un alimentador
abierto ideal que opera a una presin de 0.5 MPa con vapor extrado de la turbina. Si la entalpa del
alimentador de agua es 215 kJ/kg y la entalpa del vapor extrado es 2442 kJ/kg, la fraccin de masa de
vapor que se extrae de la turbina es del

(a) 5% (b) 10% (c) 19% (d) 9% (e) 29%

Respuesta: (c) 19%.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

h_feed=215 "kJ/kg"
h_extracted=2442 "kJ/kg"
P3=500 "kPa"
h3=ENTHALPY(Steam_NBS,x=0,P=P3)

"Balance de energa en el FWH"

h3=x_ext*h_extracted+(1-x_ext)*h_feed

Algunas soluciones errneas con equivocaciones frecuentes:

W1_ext = h_feed/h_extracted "Al usar la relacin equivocada"
W2_ext = h3/(h_extracted-h_feed) "Al usar la relacin equivocada"
W3_ext = h_feed/(h_extracted-h_feed) "Al usar la relacin equivocada"

Cap. 9-8 Tasa de flujo msico del vapor en un ciclo Rankine regenerador
Considere una planta de potencia de vapor que opera en el ciclo Rankine regenerador con un calentador
alimentador. La entalpa del vapor es 3140 kJ/kg en la entrada de la turbina, 2655 kJ/kg en el sitio de purga,
y 2346 kJ/kg en la salida de la turbina. La salida de potencia neta de la planta es 110 MW, y la fraccin de
purga de vapor fuera de la turbina para regeneracin es de 0.172. Si el trabajo de bombeo es despreciable,
la tasa de flujo msico del vapor a la entrada de la turbina es

(a) 326 kg/s (b) 149 kg/s (c) 806 kg/s (d) 288 kg/s (e) 139 kg/s

Respuesta: (b) 149 kg/s.

Solucin. Resuelto con el Software EES. Las soluciones se pueden verificar si se copian y pegan las lneas
siguientes en una pantalla EES en blanco.

h_in=3140 "kJ/kg"
h_out=2346 "kJ/kg"
h_feed=252 "kJ/kg"
h_extracted=2655 "kJ/kg"

Wnet_out=110000 "kW"
x_bleed=0.172

w_turb=(h_in-h_extracted)+(1-x_bleed)*(h_extracted-h_out)
m=Wnet_out/w_turb

Algunas soluciones errneas con equivocaciones frecuentes:

W1_mass = Wnet_out/(h_in-h_out) "Al ignorar la extraccin de vapor"
W2_mass = Wnet_out/(x_bleed*(h_in-h_out)) "Al suponer que el vapor se extrae en la entrada de la
turbina"
W3_mass = Wnet_out/(h_in-h_out-x_bleed*h_extracted) "Al usar la relacin equivocada"
Cap. 9-9 Efecto de aumentar la presin del condensador de un ciclo Rankine (concepto)
Considere un ciclo Rankine ideal simple. Si la presin del condensador se incrementa mientras se mantiene
igual el estado de la entrada de la turbina (seleccione el enunciado correcto):

(a) Se incrementar la salida de trabajo de la turbina.

(b) Decrecer la cantidad de calor rechazado.
(c) Disminuir la eficiencia del ciclo.
(d) Aumentar el contenido de humedad a la salida de la turbina.
(e) La entrada de trabajo de bombeo se incrementar.

Respuesta: (c) Disminuir la eficiencia del ciclo.

Cap. 9-10 Efecto del sobrecalentamiento en un ciclo Rankine (concepto)

Considere un ciclo Rankine ideal simple con presiones fijas en la caldera y el condensador. Si el vapor se
sobrecalienta a una temperatura ms elevada (elija el enunciado correcto):

(a) La salida de trabajo de la turbina disminuir.

(b) Decrecer la cantidad de calor rechazado.
(c) Disminuir la eficiencia del ciclo.
(d) Se incrementar el contenido de humedad a la salida de la turbina.
(e) La cantidad de entrada de calor aumentar.

Respuesta: (e) La cantidad de entrada de calor aumentar.

Cap. 9-11 Aumento de la presin de la caldera en el ciclo Rankine (concepto)

Considere un ciclo Rankine ideal simple con la presin del condensador fija. Si la presin de la caldera se
aumenta mientras se mantiene constante la temperatura a la entrada de la turbina (seleccione el enunciado
que sea correcto):

(a) La salida de trabajo de la turbina disminuir.

(b) Aumentar la cantidad de calor rechazado.
(c) La eficiencia del ciclo disminuir.
(d) Aumentar el contenido de humedad a la salida de la turbina.
(e) Disminuir la entrada de trabajo de bombeo.

Respuesta: (d) Aumentar el contenido de humedad a la salida de la turbina.

Cap. 9-12 Efecto del sobrecalentamiento en el ciclo Rankine (concepto)

Considere un ciclo Rankine ideal simple con presiones fijas en la caldera y el condensador, as como la
temperatura en la entrada de la turbina. Si el ciclo se modifica con un sobrecalentamiento ideal (seleccione
el enunciado correcto):

(a) Disminuir la salida de trabajo de la turbina.

(b) Aumentar la cantidad de calor que se rechaza.
(c) El trabajo de bombeo disminuir.
(d) El contenido de humedad en la salida de la turbina se incrementar.
(e) Decrecer la cantidad de calor que entra.

Respuesta: (b) Aumentar la cantidad de calor que se rechaza.

Cap. 9-12 Efecto de la regeneracin en el ciclo Rankine (concepto)

Considere un ciclo Rankine ideal simple con presiones fijas en la caldera y el calentador, al igual que la
temperatura en la entrada de la turbina. Si se modifica el ciclo con la regeneracin ideal que involucra una
caldera cerrada alimentadora de agua (seleccione el enunciado correcto por unidad de flujo msico del
vapor que fluye a travs de la caldera)

(a) La salida de trabajo de la turbina se incrementar.

(b) Aumentar la cantidad de calor que se rechaza.
(c) La eficiencia trmica del ciclo disminuir.
(d) La calidad del vapor en la salida de la turbina decrecer.
(e) Disminuir la cantidad de calor que entra.

Respuesta: (e) Disminuir la cantidad de calor que entra.